simulated function DrawFragCount(Canvas Canvas)
{
   local float Whiten;
   local int X,Y;

   if ( PawnOwner.PlayerReplicationInfo == None )
      return;

   Canvas.Style = Style;
   if ( bHideAllWeapons || (HudScale * WeaponScale * Canvas.ClipX <= Canvas.ClipX - 256 * Scale) )
      Y = Canvas.ClipY - 63.5 * Scale;
   else
      Y = Canvas.ClipY - 127.5 * Scale;
   if ( bHideAllWeapons )
      X = 0.5 * Canvas.ClipX - 256 * Scale;
   Canvas.CurX = X;
   Canvas.CurY = Y;
   Canvas.DrawColor = HUDColor;
   Whiten = Level.TimeSeconds - ScoreTime;
   if ( Whiten < 3.0 )
   {
      if ( HudColor == GoldColor )
         Canvas.DrawColor = WhiteColor;
      else
         Canvas.DrawColor = GoldColor;
      if ( Level.bHighDetailMode )
      {
         Canvas.CurX = X - 64 * Scale;
         Canvas.CurY = Y - 32 * Scale;
         Canvas.Style = ERenderStyle.STY_Translucent;
         Canvas.DrawTile(Texture'BotPack.HUDWeapons', 256 * Scale, 128 * Scale, 0, 128, 256.0, 128.0);
      }
      Canvas.CurX = X;
      Canvas.CurY = Y;
      Whiten = 4 * Whiten - int(4 * Whiten);
      Canvas.DrawColor = Canvas.DrawColor + (HUDColor - Canvas.DrawColor) * Whiten;
   }

   Canvas.DrawTile(Texture'BotPack.HudElements1', 128*Scale, 64*Scale, 0, 128, 128.0, 64.0);
   Canvas.DrawColor = WhiteColor;
   DrawBigNum(Canvas, PawnOwner.PlayerReplicationInfo.Score, X + 40 * Scale, Y + 16 * Scale);
}

simulated function DrawBigNum(Canvas Canvas, int Value, int X, int Y, optional float ScaleFactor)
{
   local int d, Mag, Step;
   local float UpScale;
   local byte bMinus;

   if ( ScaleFactor != 0 )
      UpScale = Scale * ScaleFactor;
   else
      UpScale = Scale;

   Canvas.CurX = X;
   Canvas.CurY = Y;
   Step = 16 * UpScale;
   if ( Value < 0 )
      bMinus = 1;
   Mag = FMin(9999, Abs(Value));

   if ( Mag >= 1000 )
   {
      Canvas.CurX -= Step;
      d = 0.001 * Mag;
      DrawDigit(Canvas, d, Step, UpScale, bMinus);
      Mag = Mag - 1000 * d;
      d = 0.01 * Mag;
      DrawDigit(Canvas, d, Step, UpScale, bMinus);
      Mag = Mag - 100 * d;
   }
   else if ( Mag >= 100 )
   {
      d = 0.01 * Mag;
      DrawDigit(Canvas, d, Step, UpScale, bMinus);
      Mag = Mag - 100 * d;
   }
   else
      Canvas.CurX += Step;

   if ( Mag >= 10 )
   {
      d = 0.1 * Mag;
      DrawDigit(Canvas, d, Step, UpScale, bMinus);
      Mag = Mag - 10 * d;
   }
   else if ( d > 0 )
      DrawDigit(Canvas, 0, Step, UpScale, bMinus);
   else
      Canvas.CurX += Step;

   DrawDigit(Canvas, Mag, Step, UpScale, bMinus);
}